;騪 稪 

       ORG 24000

       LD IX,SRED0     ;࠭ ࢮ砫 ।
       CALL SAVESRED

;। ⨯ ⥬ - TASiS  iS-DOS
       LD C,#12
       RST 16
       EXX
       LD A,(HL)  ; । ஢ਬ  
       CP 4       ;᫨  4  6,  ⥬ iS-DOS
       JP Z,SYSIS
       CP 6
       JP Z,SYSIS

       LD A,80       ; TASiS ⠭ ⢮ ᨬ  ப
       LD (LENSTR),A

SYSIS  LD C,#10      ;।  
       RST 16
       EXX
       LD BC,5
       ADD HL,BC
       LD E,(HL)
       INC HL
       LD D,(HL)
       LD (CACHE),DE

       LD C,#45      ;࠭塞 ।   䠩 ணࠬ
       RST 16
       EXX
       LD BC,-9
       ADD HL,BC
       LD DE,SRED3
       LD BC,4
       LDIR

BEG0   LD C,#43
       RST 16
       RET C

       JP Z,BEG1

       LD HL,0
FIL    EQU $-1
FIL2   EQU $-2
       LD A,H
       AND L
       LD A,0
       SCF
       RET Z

; 䠩 㪠

       LD HL,(BUF2ADR)

       LD A,"S"        ;ᥬ  0-    䨪 S
FBYTE  EQU $-1
       LD (HL),A
       INC HL
       LD (ROMADR),HL

       LD HL,EKRAN     ;뫮 $BUFER. 砫 㦥 䠩  ﬨ 
       LD (TEKSTR),HL
       DEC HL
AN0    INC HL
AN00   LD A,(HL)
       CP #0D     ;᫨ ॢ ப
       JR Z,AN0
       CP #03     ;ਧ  䠩
       JP Z,AN1

;㦥  ப  ⥪⮬
       CP ";"
       JP Z,AN2  ;᫨ ਩

;ப  . ࢮ 祭 -  
       PUSH HL
       LD HL,NAME   ;⨬    
       LD D,H
       LD E,L
       INC DE
       LD (HL)," "
       LD BC,26-1  ;⨬ ࠧ 2 
       LDIR
       POP HL

       LD DE,NAME2+1
       LD B,12      ;ᨬ 12 ᨬ  
AN4    LD A,(HL)
       CP ","
       JR Z,AN3     ; 
       LD C,A
       LD A,B
       OR A
       JR Z,AN41    ;᫨ ॡࠫ  12 ᨬ, ⠫ 㥬
       LD A,C
       LD (DE),A
       DEC B
       INC DE
AN41   INC HL
       JR AN4

AN3    PUSH HL      ;㥬  䠩  ଠ 
       LD HL,NAME2
       LD DE,NAME
       LD BC,13
       CALL $CONVERT
       POP HL
       INC HL      ;ய᪠ ஡
       LD A,(HL)
       CP " "
       JR Z,AN3

       CALL PRINT  ;   ᢥ ࠭


;HL 㪠뢠    䠩  稪
       PUSH HL  ;㦨  ப
AN7    INC HL
       LD A,(HL)
       CP #0D
       JR NZ,AN7
       INC HL
       LD (TEKSTR),HL    ;᫥騩 ᨬ  殬 ப
       POP HL

       LD C,#42
       RST 16
       RET C
       JR Z,AN5
AN6    LD A,81
       SCF
       RET

AN5    OR A
       JR NZ,AN6

       EXX         ;஥ 䠩 
       LD C,#25
       RST 16
       RET C

       EXX          ;࠭ ⥫
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,SRED1    ;࠭ ।  ன
       CALL SAVESRED

       LD A,(ADR3+2)   ;᪮쪮     ⥪饣  
       LD HL,(ADR3)
       CALL SETPORT
       EX DE,HL
       LD HL,#4000
       XOR A
       SBC HL,DE
       LD (OST),HL

       LD IX,(BUFFIL)
       XOR A
       LD HL,#02F4    ;  稪 稭 ᫥ ᠭ
       LD DE,#0100    ;㧨  
       LD C,#29
       RST 16
       RET C

       LD L,(IX+11)    ;      - 稪,
       LD H,(IX+12)
       LD DE,#02F4     ;ᠭ 
       ADD HL,DE
       LD DE,3         ; 3   JP xxxx
       ADD HL,DE
       EX DE,HL
       LD HL,0
OST    EQU $-2
       XOR A
       SBC HL,DE
       JR NC,AN51

;稪      
       LD DE,#0100      ;塞        255
       ADD IX,DE
       PUSH IX
       POP HL
       PUSH HL
       LD (NEWBUF),HL
       LD D,H
       LD E,L
       INC DE
       LD BC,(OST)
       DEC BC
       LD (HL),#FF
       LDIR
       LD A,#00      ;  塞  0 - 砫  
       LD (DE),A

       POP HL
       LD BC,(OST)  ; ⥫쭮   255 㢥稢  1,
       INC BC       ;⠪    00
       LD (OST),BC
       CALL CALCCS  ;⠥ ஫ 㬬 

       LD IX,SRED2    ;।  室 䠩
       CALL LOADSRED

       LD DE,(OST)    ;㢥稢 ࠧ 䠩   . 
       LD C,#31
       RST 16
       RET C

       LD IX,0       ;襬  255  0      
NEWBUF EQU $-2       ;室 䠩
       LD A,(ADR3+2)
       LD HL,(ADR3)
       LD C,#2A
       RST 16
       RET C

       LD IX,SRED1    ;।  ⮩ ன
       CALL LOADSRED

       LD A,(ADR3+2)  ;⠥   砫 
       LD HL,(ADR3)
       LD DE,(OST)
       ADD HL,DE
       JR NC,$+3
       INC A
       LD (ADR3),HL
       LD (ADR3+2),A

       LD IX,(BUFFIL)

AN51   LD DE,(OPIS3+26)  ; 䠩  ன
       XOR A
       LD HL,0
       SBC HL,DE         ;㬬  ⮢ 䠩  ன
       XOR A
       LD E,(IX+4)
       LD D,0
       SBC HL,DE
       LD E,(IX+5)
       SBC HL,DE
       LD E,(IX+6)
       SBC HL,DE
       PUSH HL

       LD A,(ADR3+2)   ;ᨬ  砫     稪 
       LD HL,(ADR3)    ;ᬥ饭 +4

       LD BC,(SMESH)   ;塞   砫  ᬥ饭  砩
       ADD HL,BC       ;樨 ࠧ  訢   
       ADC A,0

       LD (IX+4),L     ;ᨬ १  稪 塞 
       LD (IX+5),H
       LD (IX+6),A

       POP HL
       LD E,(IX+4)
       ADD HL,DE
       LD E,(IX+5)
       ADD HL,DE
       LD E,(IX+6)
       ADD HL,DE
       EX DE,HL      ;DE-㬬   䠩  ன (᫥ )
       XOR A
       SBC HL,HL
       SBC HL,DE     ;HL- ஫쭠 㬬 䠩  ன
       PUSH HL

       LD C,#35      ;ᨬ  ஫ 㬬  ⥫ 䠩  ன
       RST 16
       EXX
       LD DE,26
       ADD HL,DE
       POP DE
       LD (HL),E
       INC HL
       LD (HL),D

       LD C,#28     ;࠭塞 ⥫ 䠩  ன
       RST 16
       RET C

       XOR A            ;࠭塞   稪 
       LD HL,#02F4
       LD DE,#0100
       LD C,#2A
       RST 16
       RET C



;ࠡ⪠ 䠩 

       LD HL,NAME      ;७  䠩 (13 )
       LD DE,(ROMADR)
       LD BC,13
       LDIR

       LD HL,(ADR3)  ;    ਤ 塞
       LD A,(ADR3+2) ;  
       LD BC,#02F4   ;塞 ᬥ饭  ᠭ 
       ADD HL,BC
       JR NC,$+3
       INC A
       CALL SETPORT  ;A-  ,HL-   
       LD (DE),A     ;+13  砫  , ᨬ 

       INC DE
       LD A,L
       LD (DE),A     ;+14 - ᨬ     
       INC DE
       LD A,H
       LD (DE),A     ;+15
       INC DE
       EX DE,HL

       LD IX,(BUFFIL) ; 稪   0-  
       LD A,(IX+2)
       LD (HL),A      ;ᨬ   ⥫ 
       INC HL
       LD A,(IX+3)
       LD (HL),A
       INC HL

       LD A,(IX+7+4)  ; 稪  ᬥ饭 +11
       LD (HL),A      ;ᨬ  +17
       INC HL
       LD A,(IX+7+5)
       LD (HL),A
       INC HL

       LD (ROMADR),HL

       CALL LDBLK      ;७ 䠩  ன   室 䠩
       RET C

       LD HL,(TEKSTR)  ;⠭   䠩-筨
       JP AN00         ; ᫥饩 ப


; ନ஢    砭  䠩
AN1
       LD IX,SRED2      ;।  室 䠩 
       CALL LOADSRED


       LD HL,(ROMADR)
       LD (HL),#FF
       INC HL
       LD DE,(BUF2ADR)
       PUSH DE
       XOR A
       SBC HL,DE
       EX DE,HL         ;DE - ᪮쪮     
       LD (AN11),DE

       LD HL,(BUF2ADR)  ;⠥ ஫ 㬬 ନ஢
       LD B,D           ; 
       LD C,E
       CALL CALCCS

       POP IX      ;࠭塞 ନ஢    室 䠩
       XOR A
       LD HL,0
       LD C,#2A
       RST 16
       RET C

       LD HL,$HRUST
       LD DE,(AN11)
       XOR A
       SBC HL,DE
       LD B,H
       LD C,L
       LD (AN12),BC   ;᪮쪮   FF  
       DEC BC

       LD HL,(BUF2ADR)   ;塞    砫  祭ﬨ 255
       PUSH HL
       LD D,H
       LD E,L
       INC DE
       LD (HL),#FF
       LDIR

       LD HL,(BUF2ADR) ;  뢠 ᪠
       LD BC,(AN12)
       CALL CALCCS

       POP IX         ;襬   砫   室 䠩
       LD DE,0        ;᪮쪮   
AN12   EQU $-2
       XOR A
       LD HL,0        ;  ᫥ 砭 ⥫ 
AN11   EQU $-2
       LD C,#2A
       RST 16
       RET C


;㧪 ᯠ騪   㫥

       LD HL,(BUFFIL)  ;⨬      㫨
       LD D,H
       LD E,L
       INC DE
       LD BC,$LENMOD-1
       LD (HL),0
       LDIR

       LD IX,SRED3    ;।  ⮩ ணࠬ.    ணࠬ
       CALL LOADSRED  ; ᯮ 䠩 㫥

       LD HL,DEHR    ;뢠 䠩  ᯠ騪
       LD C,#25
       RST 16
       RET C

       EXX            ;⥫ ᯠ騪
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,(BUFFIL)  ;㦠 ᯠ騪
       LD DE,(OPIS3+14)
       XOR A
       LD HL,0
       LD C,#29
       RST 16
       RET C


       LD HL,CH128    ;뢠 䠩  㫥 ஢ન  128
       LD C,#25
       RST 16
       RET C

       EXX            ;⥫ 
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,(BUFFIL)  ;㦠 
       LD DE,$LENDEP  ;⭮⥫쭮 砫   㤥 +#0100
       ADD IX,DE
       LD DE,(OPIS3+14)
       XOR A
       LD HL,0
       LD C,#29
       RST 16
       RET C

       LD HL,CHNOV    ;뢠 䠩  㫥 ஢ન  
       LD C,#25
       RST 16
       RET C

       EXX            ;⥫ 
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,(BUFFIL)  ;㦠 
       LD DE,$LENDEP+$LEN128  ;⭮⥫쭮 砫   㤥 +#0200
       ADD IX,DE
       LD DE,(OPIS3+14)
       XOR A
       LD HL,0
       LD C,#29
       RST 16
       RET C

       LD HL,MENU    ;뢠 䠩  㫥 
       LD C,#25
       RST 16
       RET C

       EXX            ;⥫ 
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,(BUFFIL)  ;㦠 

     ;⭮⥫쭮 砫   㤥 +#0300
       LD DE,$LENDEP+$LEN128+$LENNOV
       ADD IX,DE
       LD DE,(OPIS3+14) ;   #0200 
       XOR A
       LD HL,0
       LD C,#29
       RST 16
       RET C


       LD HL,FUNC    ;뢠 䠩  㫥 㭪権
       LD C,#25
       RST 16
       RET C

       EXX            ;⥫ 
       LD DE,OPIS3
       LD BC,32
       LDIR

       LD IX,(BUFFIL)  ;㦠 
     ;⭮⥫쭮 砫   㤥 +#0500
       LD DE,$LENDEP+$LEN128+$LENNOV+$LENMENU
       ADD IX,DE
       LD DE,(OPIS3+14) ;   #0100 
       XOR A
       LD HL,0
       LD C,#29
       RST 16
       RET C

       LD HL,(BUFFIL)     ;⠥  ᯠ騪   㫥
       LD BC,$LENMOD      ;  䠩 - #0600 
       CALL CALCCS

       LD IX,SRED2       ;।   室 䠩
       CALL LOADSRED

       LD IX,(BUFFIL)    ;襬  㫨  室 䠩
       XOR A
       LD HL,$HRUST
       LD DE,$LENMOD     ;  㫥 
       LD C,#2A
       RST 16
       RET C

       LD DE,(KS)  ;⥫  ஫쭮 㬬  㫥
       XOR A
       SBC HL,HL
       SBC HL,DE
       PUSH HL

       LD C,#35    ;࠭  室 䠩  ⥫ 䠩
       RST 16
       EXX
       LD DE,26
       ADD HL,DE
       POP DE
       LD (HL),E
       INC HL
       LD (HL),D

       LD C,#28    ;࠭  ⥫ 䠩
       RST 16
       RET C

       LD C,#45     ;⠭ ࢮ砫 ।
       RST 16
       EXX
       LD HL,SRED0
       LD BC,4
       LDIR

       JP QUIT

;㦥 ਩ (ப 稭  ᨬ ;)
;ய᪠  ப
AN2    INC HL
       LD A,(HL)
       CP #0D
       JR NZ,AN2
       JP AN0




QUIT   LD C,2
       RST 16
       RET C

       XOR A
       LD A,#F4
       RET


; 
BEG2   RES 5,A
       CP "R"      ; ᡮન  
       JR Z,BEG22

       CP "O"      ; 室 䠩
       JR Z,BEG21

       JP BEG0

;祭 ० ᡮન   
BEG22
       LD HL,#8000
       LD (SMESH),HL
       XOR A        ;㡨ࠥ ⠭ 7-    
       LD (SETP0),A
       LD A,2       ;塞  ࠬ   ᫮ 2
       LD (SETP1),A
       LD A,#FF     ;    "S",  #FF
       LD (FBYTE),A
       JP BEG0

; /O - 㪠 室 䠩
BEG21  EXX          ;HL 㪠뢠  "/"
       INC HL       ;㪠뢠   ""
       INC HL       ;HL 㪠뢠   ᨬ  䠩
       LD DE,OPIS2  ;८ࠧ㥬  室 䠩  11  ⥫ DE
       LD C,#46
       RST 16
       RET C

       LD C,#45   ;७   ⥬  ⥫
       RST 16
       EXX
       DEC HL
       DEC HL
       LD D,(HL)
       DEC HL
       LD E,(HL)
       LD (OPIS2+30),DE

       LD C,#24       ;㤠塞 䠩, ᫨  
       LD HL,OPIS2
       RST 16
       RET C

       LD HL,OPIS2   ;ᮧ 室 䠩    砫 
       LD C,#23      ; 㦥   ⥫
       RST 16
       RET C

       LD IX,SRED2
       CALL SAVESRED

       OR #FF
       LD (FIL2),A

       LD C,2
       RST 16
       RET C

       JP BEG0

; 䠩-ࠬ  
BEG1   OR A
       JR NZ,BEG2    ;

;㪠 䠩-ࠬ
       EXX
       LD C,#25
       RST 16
       RET C

       EXX
       LD DE,OPIS
       LD BC,32
       LDIR

;⠥    ᮧ 室 䠩
       LD DE,(OPIS+14)  ; 室 䠩  ᯨ᪮ 
       LD HL,EKRAN      ;뫮 $BUFER,  㧨  ࠭  (#4800)
       ADD HL,DE
       LD (BUF2ADR),HL

       LD HL,$BUFER    ;  ஢ 䠩  㤥
       LD (BUFFIL),HL  ;ᯮ ࠧ  殬 ணࠬ

       LD DE,BUFLEN    ;    16
       ADD HL,DE
       CALL CACHEMEM   ;    ?
       RET C

       LD DE,(OPIS+14)  ;㦠 室 䠩  
       LD C,#29
       LD IX,EKRAN      ;뫮 $BUFER
       XOR A
       LD HL,0
       RST 16
       RET C

       OR #FF      ;ਧ,  室 䠩 㪠  㦥
       LD (FIL),A
       JP BEG0


SAVESRED
       XOR A
       LD C,#36
       RST 16
       RET

LOADSRED
       XOR A
       LD C,#37
       RST 16
       RET

;⠭    A      HL  ᨬ   AHL
SETPORT
       PUSH HL
       PUSH AF
       LD A,H
       AND %11000000
       LD H,A
       POP AF
       SLA H
       RLA
       SLA H
       RLA
       OR %10000000
SETP0  EQU $-1        ; ० ᡮન     ⠭ 7- 
       POP HL
       PUSH AF
       LD A,H
       AND %00111111
       LD H,A
       POP AF
       ADD A,0       ; ० ᡮન    塞   ᫮ 2
SETP1  EQU $-1       ;⠪    ࠬ 稭   2
       LD (BANK),A
       LD (BADR),HL
       RET


;  ஫쭮 㬬  HL  BC .   HL  ࠭
; KS.
CALCCS PUSH IX
       PUSH BC
       PUSH AF
       PUSH DE
       LD IX,(KS)
       LD D,0
1$     LD A,(HL)
       LD E,A
       ADD IX,DE
       INC HL
       DEC BC
       LD A,B
       OR C
       JR NZ,1$
       PUSH IX
       POP HL
       LD (KS),HL
       POP DE
       POP AF
       POP BC
       POP IX
       RET

;஢ઠ -    HL  .
;CF -  , 訡 130
CACHEMEM
       PUSH DE
       EX DE,HL
       LD HL,(CACHE)
       DEC HL
       OR A
       SBC HL,DE
       POP DE
       RET NC
       LD A,130
       RET


;७ 䠩  ன   室 䠩.
;뢠 0-   砫   
LDBLK
       XOR A
       SBC HL,HL
       LD (FADR),HL      ;⥪   䠩  ன = 0
       LD (FADR+2),A
       LD HL,(OPIS3+14)  ; 
       LD A,(OPIS3+16)
       LD (FLEN),HL
       LD (FLEN+2),A

LDBLK2 XOR A
       LD (DOPLEN),A
       LD HL,(BUFFIL)
       LD (ADRBUF),HL

       LD HL,(ADR3)    ;⠥       
       LD A,(ADR3+2)
       CALL SETPORT
       LD A,H          ;᫨ 稭   0   
       OR L
       JR NZ,LDBLK0
       INC A           ; 塞 ⥫  0  ७ᨬ
       LD (DOPLEN),A   ;ଠ樨
       INC HL          ;稭    1
       LD (BADR),HL
       LD HL,(ADRBUF)
       LD (HL),0
       INC HL
       LD (ADRBUF),HL
LDBLK0                 ;᪮쪮     ⥪饣  ?
       LD HL,#4000
       LD DE,(BADR)
       XOR A
       SBC HL,DE      ;HL - ⮪   ⥪饣  
       LD (QUANT),HL

       LD A,(FLEN+2)  ; 㯭     AHL ⠥
       LD B,A         ;⠢  䠩  ன BDE
       LD DE,(FLEN)
       XOR A
       SBC HL,DE
       SBC A,B
       JR C,LDBLK1

;⮪  頥   ⥪饣  
       LD DE,(FLEN)
       CALL MOVE       ;७ᨬ ⠯ १  
       RET C

;       LD IX,SRED1      ;।  ன
;       CALL LOADSRED

;       LD IX,(ADRBUF)   ;㦠 ⮪ 
;       LD HL,(FADR)
;       LD A,(FADR+2)
;       LD DE,(FLEN)
;       LD C,#29
;       RST 16
;       RET C

;       LD HL,(FLEN)      ;⠥  ⪠ 
;       LD DE,(DOPLEN)
;       LD D,0
;       ADD HL,DE
;       LD B,H
;       LD C,L
;       PUSH BC
;       LD HL,(BUFFIL)
;       CALL CALCCS

;       LD IX,SRED2    ;।  䠩 
;       CALL LOADSRED

;       POP DE        ;塞  室 䠩 ⮪ 
;       LD C,#31
;       RST 16
;       RET C

;       LD A,(ADR3+2)  ;襬 ⮪   䠩  
;       LD HL,(ADR3)
;       LD IX,(BUFFIL)
;       LD C,#2A
;       RST 16
;       RET C

       LD HL,(FLEN)
       LD DE,(DOPLEN)
       LD D,0
       ADD HL,DE
       EX DE,HL
       LD A,(ADR3+2) ;⠥ ᫥騩   
       LD HL,(ADR3)
       ADD HL,DE     ;DE ⠭ ࠭ -  - 塞   
       JR NC,$+3
       INC A
       LD (ADR3),HL
       LD (ADR3+2),A

       XOR A
       RET

;⮪      ⥪饣  
LDBLK1

       LD DE,(QUANT)
       CALL MOVE
       RET C

;       LD IX,SRED1      ;।  ன
;       CALL LOADSRED

;       LD IX,(ADRBUF)   ;㦠 ⮫쪮 , ᪮쪮 㯭   
;       LD HL,(FADR)
;       LD A,(FADR+2)
;       LD DE,(QUANT)
;       LD C,#29
;       RST 16
;       RET C

;       LD HL,(QUANT)      ;⠥  㦥 ᪠ 䠩
;       LD DE,(DOPLEN)
;       LD D,0
;       ADD HL,DE
;       LD B,H
;       LD C,L
;       PUSH BC
;       LD HL,(BUFFIL)
;       CALL CALCCS

;       LD IX,SRED2    ;।  䠩 
;       CALL LOADSRED

;       POP DE        ;塞  室 䠩 ⢮ 㦥 
;       LD C,#31
;       RST 16
;       RET C

;       LD A,(ADR3+2)  ;襬 ⮪   䠩  
;       LD HL,(ADR3)
;       LD IX,(BUFFIL)
;       LD C,#2A
;       RST 16
;       RET C

       LD HL,(QUANT)
       LD DE,(DOPLEN)
       LD D,0
       ADD HL,DE
       EX DE,HL
       LD A,(ADR3+2) ;⠥ ᫥騩   
       LD HL,(ADR3)
       ADD HL,DE     ;DE ⠭ ࠭ -  - 塞   
       JR NC,$+3
       INC A
       LD (ADR3),HL
       LD (ADR3+2),A

       LD A,(FADR+2) ;⠥ ᫥騩   
       LD HL,(FADR)
       LD DE,(QUANT) ;᪮쪮  뫮 㯭   
       ADD HL,DE
       JR NC,$+3
       INC A
       LD (FADR),HL
       LD (FADR+2),A

       LD HL,(FLEN)    ;㬥蠥 ⠢  
       LD A,(FLEN+2)
       OR A
       SBC HL,DE
       JR NC,$+3
       DEC A
       LD (FLEN),HL
       LD (FLEN+2),A

       LD B,A     ;᫨  ⠫, 室
       LD A,H
       OR L
       OR B
       RET Z

       JP LDBLK2



;DE-⢮   ७
MOVE
       LD (MOVEC),DE
       LD HL,(FADR)
       LD (FADR2),HL
       LD A,(FADR+2)
       LD (FADR2+2),A
       LD HL,(ADR3)
       LD A,(ADR3+2)
       LD (ADR32),HL
       LD (ADR32+2),A
       LD A,(DOPLEN)
       LD (MOVED),A

MOVE0  XOR A          ;஢ઠ   㦠   
       LD HL,BUFLEN
       LD DE,(MOVEC)
       SBC HL,DE
       JR C,MOVE1

;⮪ 䠩 楫   
       LD IX,SRED1    ;। 䠩  ன
       CALL LOADSRED

       LD IX,(ADRBUF)    ;㧨 ⮪ 䠩
       LD HL,(FADR2)
       LD A,(FADR2+2)
       LD DE,(MOVEC)
       LD C,#29
       RST 16
       RET C

       LD HL,(MOVEC)      ;⠥  ⪠ 
       LD DE,(MOVED)      ; ⮬  0  砫  , ᫨ 
       LD D,0
       ADD HL,DE
       LD B,H
       LD C,L
       PUSH BC
       LD HL,(BUFFIL)
       CALL CALCCS


       LD IX,SRED2   ;। 室 䠩
       CALL LOADSRED

       POP DE        ;㢥稢 室 䠩  ⠭ - 
       LD C,#31      ;+0-  砫  , ᫨ 
       RST 16
       RET C

       LD IX,(BUFFIL)   ;襬 ⮪  室 䠩
       LD HL,(ADR32)    ;⢮    - ࠭ ⠭  DE
       LD A,(ADR32+2)
       LD C,#2A
       RST 16
       RET

;⮪ 䠩    
MOVE1  LD IX,SRED1    ;। 䠩  ன
       CALL LOADSRED

       LD IX,(ADRBUF)    ;㧨  䠩
       LD HL,(FADR2)
       LD A,(FADR2+2)
       LD DE,BUFLEN
       LD C,#29
       RST 16
       RET C

       LD HL,BUFLEN      ;⠥  ⪠   ⮬ 0-  0 
       LD DE,(MOVED)     ;砫  , ᫨ 
       LD D,0
       ADD HL,DE
       LD B,H
       LD C,L
       PUSH BC
       LD HL,(BUFFIL)
       CALL CALCCS


       LD IX,SRED2   ;। 室 䠩
       CALL LOADSRED

       POP DE        ;㢥稢 室 䠩  ⠭ ⢮ 
       LD C,#31      ;+0-  砫  , ᫨ 
       RST 16
       RET C

       LD IX,(BUFFIL)   ;襬 㦥  室 䠩
       LD HL,(ADR32)    ;⢮   DE ࠭ ⠭
       LD A,(ADR32+2)
       LD C,#2A
       RST 16
       RET C

       LD DE,BUFLEN
       LD HL,(FADR2)   ;㢥稢   䠩-筨
       LD A,(FADR2+2)
       ADD HL,DE
       JR NC,$+3
       INC A
       LD (FADR2),HL
       LD (FADR2+2),A


       LD HL,BUFLEN
       LD DE,(MOVED)
       LD D,0
       ADD HL,DE
       EX DE,HL
       LD A,(ADR32+2) ;⠥ ᫥騩   
       LD HL,(ADR32)
       ADD HL,DE     ;DE ⠭ ࠭ -  - 塞   
       JR NC,$+3
       INC A
       LD (ADR32),HL
       LD (ADR32+2),A

       XOR A          ;᫨ 0-   砫   㦥 , 
       LD (MOVED),A   ;  ᯮ㥬,  㦥 ⮫쪮  ࠧ
       LD HL,(BUFFIL) ;   뢠 頥  ਣ,
       LD (ADRBUF),HL ;  0-   砫  

       XOR A         ;㬥蠥 ⢮ ⠢ 
       LD HL,(MOVEC)
       LD DE,BUFLEN
       SBC HL,DE
       LD (MOVEC),HL

       JP MOVE0

MOVEC  DEFW 0
MOVED  DEFB 0  ; DOPLEN
FADR2  DEFS 3  ; FADR
ADR32  DEFS 3  ; ADR32



ADRBUF DEFW 0
DOPLEN DEFB 0
BANK   DEFB 0
BADR   DEFS 3
QUANT  DEFW 0
FLEN   DEFS 3
FADR   DEFS 3


;  㥬   NAME2  0- ப ࠭
PRINT  PUSH HL
       PUSH DE
       PUSH BC
       PUSH AF

       LD HL,0     ;⠭ न  
PRTCRD EQU $-2
       LD C,#0C
       RST 16

       LD A,(PRTCRD)  ;᫨ 㦥 ⠫ ப "Processing"
       OR A           ;室 ࠧ    
       JR NZ,PRT2

       LD HL,PRTSTR   ;᫨ 楤 뫠 맢  ࠧ,
       LD C,#6C       ;⠥ ப "Processing"
       RST 16
       LD A,11        ;⠭  न 
       LD (PRTCRD),A

PRT2   LD B,42  ;⢮ ᨬ  ப ࠭ ( 祭  iS-DOS)
LENSTR EQU $-1
       LD C,#0A
       LD HL,NAME2
PRT0   LD A,(HL)
       CP #0D
       JR Z,PRT1
       RST 16
       INC HL
       DJNZ PRT0
PRT1   LD A," "   ;⮪ ப 뢠 ஡
       RST 16
       DJNZ PRT1

       POP AF
       POP BC
       POP DE
       POP HL
       RET

PRTSTR DEFM "Processing:"
       DEFB 13


SRED0  DEFS 4    ;砫쭠 । 맮 ணࠬ
SRED1  DEFS 4    ;। 䠩  ன
SRED2  DEFS 4    ;। 䠩  
SRED3  DEFS 4    ;।   䠩 ணࠬ
OPIS   DEFS 32   ;⥫ 室 䠩
OPIS2  DEFS 11   ;⥫ 䠩  
       DEFB %00000001
       DEFW 0
       DEFW $GAMES  ;3   䠩
       DEFB 0
       DEFS 15
OPIS3  DEFS 32   ;⥫ 䠩  ன
NAME   DEFS 13   ;  ନ஢  
NAME2  DEFS 13   ;  ஢  
       DEFB 13
TEKSTR DEFW 0
KS     DEFW 0    ;஫쭠 㬬 室 䠩
BUF2ADR DEFW 0   ;   ᮧ  
BUFFIL  DEFW 0   ;   ஢ 䠩
ROMADR  DEFW 0   ;⥪騩      ନ஢  
ADR3    DEFW $GAMES ;⥪騩    ਤ  ନ஢ 
        DEFB 0
DEHR    DEFM "dehrust cod"
CH128   DEFM "check128cod"
CHNOV   DEFM "checkAlfcod"
MENU    DEFM "menu    cod"
FUNC    DEFM "func    cod"
CACHE   DEFW 0   ; 
SMESH   DEFW 0   ;ᬥ饭      ਤ. 㦭 
                 ; 樨 ࠧ  訢 ।⢥  
                 ;⠢.  ⮬ 砥  㤥 祭 #8000

BUFLEN  EQU 8192   ;   㧪 
EKRAN   EQU #4800  ;  ࠭    㧪 室
                   ;⥪⮢ 䠩
